NAME

       Mojo::Base - Minimal base class for Mojo projects

SYNOPSIS

         package Cat;
         use Mojo::Base -base;

         has name => 'Nyan';
         has ['age', 'weight'] => 4;

         package Tiger;
         use Mojo::Base 'Cat';

         has friend  => sub { Cat->new };
         has stripes => 42;

         package main;
         use Mojo::Base -strict;

         my $mew = Cat->new(name => 'Longcat');
         say $mew->age;
         say $mew->age(3)->weight(5)->age;

         my $rawr = Tiger->new(stripes => 38, weight => 250);
         say $rawr->tap(sub { $_->friend->name('Tacgnol') })->weight;

DESCRIPTION

       Mojo::Base is a simple base class for Mojo projects with fluent interfaces.

         # Automatically enables "strict", "warnings", "utf8" and Perl 5.16 features
         use Mojo::Base -strict;
         use Mojo::Base -base;
         use Mojo::Base 'SomeBaseClass';
         use Mojo::Base -role;

       All four forms save a lot of typing. Note that role support depends on Role::Tiny
       (2.000001+).

         # use Mojo::Base -strict;
         use strict;
         use warnings;
         use utf8;
         use feature ':5.16';
         use mro;

         # use Mojo::Base -base;
         use strict;
         use warnings;
         use utf8;
         use feature ':5.16';
         use mro;
         push @ISA, 'Mojo::Base';
         sub has { Mojo::Base::attr(__PACKAGE__, @_) }

         # use Mojo::Base 'SomeBaseClass';
         use strict;
         use warnings;
         use utf8;
         use feature ':5.16';
         use mro;
         require SomeBaseClass;
         push @ISA, 'SomeBaseClass';
         sub has { Mojo::Base::attr(__PACKAGE__, @_) }

         # use Mojo::Base -role;
         use strict;
         use warnings;
         use utf8;
         use feature ':5.16';
         use mro;
         use Role::Tiny;
         sub has { Mojo::Base::attr(__PACKAGE__, @_) }

       On Perl 5.20+ you can also use the "-signatures" flag with all four forms and enable
       support for subroutine signatures.

         # Also enable signatures
         use Mojo::Base -strict, -signatures;
         use Mojo::Base -base, -signatures;
         use Mojo::Base 'SomeBaseClass', -signatures;
         use Mojo::Base -role, -signatures;

       If you have Future::AsyncAwait 0.52+ installed you can also use the "-async_await" flag to
       activate the "async" and "await" keywords to deal much more efficiently with promises.
       Note that this feature is EXPERIMENTAL and might change without warning!

         # Also enable async/await
         use Mojo::Base -strict, -async_await;
         use Mojo::Base -base, -signatures, -async_await;

       This will also disable experimental warnings on versions of Perl where this feature was
       still experimental.

FLUENT INTERFACES

       Fluent interfaces are a way to design object-oriented APIs around method chaining to
       create domain-specific languages, with the goal of making the readability of the source
       code close to written prose.

         package Duck;
         use Mojo::Base -base, -signatures;

         has 'name';

         sub quack ($self) {
           my $name = $self->name;
           say "$name: Quack!"
         }

       Mojo::Base will help you with this by having all attribute accessors created with "has"
       (or "attr") return their invocant ($self) whenever they are used to assign a new attribute
       value.

         Duck->new->name('Donald')->quack;

       In this case the "name" attribute accessor is called on the object created by "Duck->new".
       It assigns a new attribute value and then returns the "Duck" object, so the "quack" method
       can be called on it afterwards. These method chains can continue until one of the methods
       called does not return the "Duck" object.

FUNCTIONS

       Mojo::Base implements the following functions, which can be imported with the "-base" flag
       or by setting a base class.

   has
         has 'name';
         has ['name1', 'name2', 'name3'];
         has name => 'foo';
         has name => sub {...};
         has ['name1', 'name2', 'name3'] => 'foo';
         has ['name1', 'name2', 'name3'] => sub {...};
         has name => sub {...}, weak => 1;
         has name => undef, weak => 1;
         has ['name1', 'name2', 'name3'] => sub {...}, weak => 1;

       Create attributes for hash-based objects, just like the "attr" method.

METHODS

       Mojo::Base implements the following methods.

   attr
         $object->attr('name');
         SubClass->attr('name');
         SubClass->attr(['name1', 'name2', 'name3']);
         SubClass->attr(name => 'foo');
         SubClass->attr(name => sub {...});
         SubClass->attr(['name1', 'name2', 'name3'] => 'foo');
         SubClass->attr(['name1', 'name2', 'name3'] => sub {...});
         SubClass->attr(name => sub {...}, weak => 1);
         SubClass->attr(name => undef, weak => 1);
         SubClass->attr(['name1', 'name2', 'name3'] => sub {...}, weak => 1);

       Create attribute accessors for hash-based objects, an array reference can be used to
       create more than one at a time.  Pass an optional second argument to set a default value,
       it should be a constant or a callback. The callback will be executed at accessor read time
       if there's no set value, and gets passed the current instance of the object as first
       argument. Accessors can be chained, that means they return their invocant when they are
       called with an argument.

       These options are currently available:

       weak
           weak => $bool

         Weaken attribute reference to avoid circular references and memory leaks.

   new
         my $object = SubClass->new;
         my $object = SubClass->new(name => 'value');
         my $object = SubClass->new({name => 'value'});

       This base class provides a basic constructor for hash-based objects. You can pass it
       either a hash or a hash reference with attribute values.

   tap
         $object = $object->tap(sub {...});
         $object = $object->tap('some_method');
         $object = $object->tap('some_method', @args);

       Tap into a method chain to perform operations on an object within the chain (also known as
       a K combinator or Kestrel).  The object will be the first argument passed to the callback,
       and is also available as $_. The callback's return value will be ignored; instead, the
       object (the callback's first argument) will be the return value. In this way, arbitrary
       code can be used within (i.e., spliced or tapped into) a chained set of object method
       calls.

         # Longer version
         $object = $object->tap(sub { $_->some_method(@args) });

         # Inject side effects into a method chain
         $object->foo('A')->tap(sub { say $_->foo })->foo('B');

   with_roles
         my $new_class = SubClass->with_roles('SubClass::Role::One');
         my $new_class = SubClass->with_roles('+One', '+Two');
         $object       = $object->with_roles('+One', '+Two');

       Create a new class with one or more Role::Tiny roles. If called on a class returns the new
       class, or if called on an object reblesses the object into the new class. For roles
       following the naming scheme "MyClass::Role::RoleName" you can use the shorthand
       "+RoleName". Note that role support depends on Role::Tiny (2.000001+).

         # Create a new class with the role "SubClass::Role::Foo" and instantiate it
         my $new_class = SubClass->with_roles('+Foo');
         my $object    = $new_class->new;

SEE ALSO

       Mojolicious, Mojolicious::Guides, <https://mojolicious.org>.