Provided by: manpages-zh_1.6.3.6-1_all 
NAME
perlfaq9 - 網路 (2003/01/31 17:36:57 )
DESCRIPTION 描述
網路通訊，網際網路以及少量有關 web 的內容
What is the correct form of response from a CGI script?
(Alan Flavell <flavell+www@a5.ph.gla.ac.uk> answers...)
The Common Gateway Interface (CGI) specifies a software interface between a program ("CGI
script") and a web server (HTTPD). It is not specific to Perl, and has its own FAQs and
tutorials, and usenet group, comp.infosystems.www.authoring.cgi
The original CGI specification is at: http://hoohoo.ncsa.uiuc.edu/cgi/
Current best-practice RFC draft at: http://CGI-Spec.Golux.Com/
Other relevant documentation listed in: http://www.perl.org/CGI_MetaFAQ.html
These Perl FAQs very selectively cover some CGI issues. However, Perl programmers are
strongly advised to use the CGI.pm module, to take care of the details for them.
The similarity between CGI response headers (defined in the CGI specification) and HTTP
response headers (defined in the HTTP specification, RFC2616) is intentional, but can
sometimes be confusing.
The CGI specification defines two kinds of script: the "Parsed Header" script, and the
"Non Parsed Header" (NPH) script. Check your server documentation to see what it supports.
"Parsed Header" scripts are simpler in various respects. The CGI specification allows any
of the usual newline representations in the CGI response (it's the server's job to create
an accurate HTTP response based on it). So "\n" written in text mode is technically
correct, and recommended. NPH scripts are more tricky: they must put out a complete and
accurate set of HTTP transaction response headers; the HTTP specification calls for
records to be terminated with carriage-return and line-feed, i.e ASCII \015\012 written in
binary mode.
Using CGI.pm gives excellent platform independence, including EBCDIC systems. CGI.pm
selects an appropriate newline representation ($CGI::CRLF) and sets binmode as
appropriate.
我的 CGI 指令碼從命令列執行正常，但是在瀏覽器中不行 (500 Server Error)。
可能有很多事錯了。可以仔細閱讀 "Troubleshooting Perl CGI scripts" guide, 位置是
http://www.perl.org/troubleshooting_CGI.html
如果接下來，你能證明你已閱讀了 FAQ 並且你的問題不是那麼簡單，非叄言兩語即可回答的話，那麼
您 post到 comp.infosystems.www.authoring.cgi上（如果是有關 HTTP 、 HTML ，或 CGI通訊協
定）的問題可能也會得到口氣和緩而有用的答覆。表面上看似 Perl，但骨子裡是 CGI之類的問題，如
果 post到 comp.lang.perl.misc人家可能就不會這麼樂意地接受了。
幾個實用的 FAQ，相關文件和查錯嚮導列在 CGI Meta FAQ 中：
http://www.perl.org/CGI_MetaFAQ.html
如何從 CGI 程式中得到好一點的錯誤提示？
Use the CGI::Carp module. It replaces "warn" and "die", plus the normal Carp modules
"carp", "croak", and "confess" functions with more verbose and safer versions. It still
sends them to the normal server error log.
use CGI::Carp;
warn "This is a complaint";
die "But this one is serious";
The following use of CGI::Carp also redirects errors to a file of your choice, placed in a
BEGIN block to catch compile-time warnings as well:
BEGIN {
use CGI::Carp qw(carpout);
open(LOG, ">>/var/local/cgi-logs/mycgi-log")
or die "Unable to append to mycgi-log: $!\n";
carpout(*LOG);
}
You can even arrange for fatal errors to go back to the client browser, which is nice for
your own debugging, but might confuse the end user.
use CGI::Carp qw(fatalsToBrowser);
die "Bad error here";
Even if the error happens before you get the HTTP header out, the module will try to take
care of this to avoid the dreaded server 500 errors. Normal warnings still go out to the
server error log (or wherever you've sent them with "carpout") with the application name
and date stamp prepended.
如何將字串中的 HTML 刪除？
最正確（儘管不是最快）的方法是使用 HTML::Parse模組（可由 CPAN取得，是所有寫 Web程式者必備
的 libwww-perl 套件的一部分）。另一中最正確的辦法是使用 HTML::FormatText，它不僅刪除了
HTML，同時也試圖對結果文字進行簡單的格式化。
許多人嘗試用簡陋的正規表示式來解決這個問題，譬如說像 "s/<.*?>//g"，但這個式子在很多情況下
會失敗，因為要處理的字串可能會跨越斷行字元，也可能含有被 quote【跳脫】的箭頭號，或有 HTML
comment出現；再加上一些疏忽，譬如，人們常忘了轉換如 < 的 entities（跳脫字 元"<"）。
以下這個「簡陋」的方法對大多數的檔案都有效：
#!/usr/bin/perl -p0777
s/<(?:[^>'"]*⎪(['"]).*?\1)*>//gs
如果您想要更完整的解法，請看叄部曲的 striphtml 程式，
http://www.cpan.org/authors/Tom_Christiansen/scripts/striphtml.gz .
Here are some tricky cases that you should think about when picking a solution:
<IMG SRC = "foo.gif" ALT = "A > B">
<IMG SRC = "foo.gif"
ALT = "A > B">
<!-- <A comment> -->
<script>if (a<b && a>c)</script>
<# Just data #>
<![INCLUDE CDATA [ >>>>>>>>>>>> ]]>
If HTML comments include other tags, those solutions would also break on text like this:
<!-- This section commented out.
<B>You can't see me!</B>
-->
如何萃取 URL?
可以簡單地從 HTML 中得到所有種類的 URL，只要使用 "HTML::SimpleLinkExtor" 模組，它可以處理
錨，影象，物件，楨，其他包含 URL 的標籤。如果需要更復雜的東西，可以建立 "HTML::LinkExtor"
的子類或使用 "HTML::Parser". 你甚至可以用 "HTML::SimpleLinkExtor" 作為範例，來書寫適合你特
殊需要的程式。
You can use URI::Find to extract URLs from an arbitrary text document.
Less complete solutions involving regular expressions can save you a lot of processing
time if you know that the input is simple. One solution from Tom Christiansen runs 100
times faster than most module based approaches but only extracts URLs from anchors where
the first attribute is HREF and there are no other attributes.
#!/usr/bin/perl -n00
# qxurl - tchrist@perl.com
print "$2\n" while m{
< \s*
A \s+ HREF \s* = \s* (["']) (.*?) \1
\s* >
}gsix;
如何從使用者的機器上下載檔案？如何開啟其他機器上的檔案？
In this case, download means to use the file upload feature of HTML forms. You allow the
web surfer to specify a file to send to your web server. To you it looks like a download,
and to the user it looks like an upload. No matter what you call it, you do it with
what's known as multipart/form-data encoding. The CGI.pm module (which comes with Perl as
part of the Standard Library) supports this in the start_multipart_form() method, which
isn't the same as the startform() method.
See the section in the CGI.pm documentation on file uploads for code examples and details.
如何在 HTML 新增一個彈出選單?
用 <SELECT> 和 <OPTION>這兩個標籤。 CGI.pm模組（可由 CPAN取得）對這個 widget【此指跳出式選
單這個介面成分】還有許多其他的介面成分都有支援【即有製作動態標籤的函式】，其中有些是以巧妙
模擬的方 式達成。
如何獲取 HTML 檔案?
有一個方法是，如果您的系統上裝有 lynx一類的文字模式的 HTML瀏覽器的話，那麼可以這麼做：
$html_code = `lynx -source $url`;
$text_data = `lynx -dump $url`;
收錄在 CPAN裡的 libwww-perl (LWP)模組則提供了更強的方法來做這件事。它不但可鑽過
proxies，而且也不需要 lynx：
# simplest version
use LWP::Simple;
$content = get($URL);
# or print HTML from a URL
use LWP::Simple;
getprint "http://www.linpro.no/lwp/";
# or print ASCII from HTML from a URL
# also need HTML-Tree package from CPAN
use LWP::Simple;
use HTML::Parser;
use HTML::FormatText;
my ($html, $ascii);
$html = get("http://www.perl.com/");
defined $html
or die "Can't fetch HTML from http://www.perl.com/";
$ascii = HTML::FormatText->new->format(parse_html($html));
print $ascii;
如何根據提交的內容自動生成一個 HTML ?
If you're submitting values using the GET method, create a URL and encode the form using
the "query_form" method:
use LWP::Simple;
use URI::URL;
my $url = url('http://www.perl.com/cgi-bin/cpan_mod');
$url->query_form(module => 'DB_File', readme => 1);
$content = get($url);
If you're using the POST method, create your own user agent and encode the content
appropriately.
use HTTP::Request::Common qw(POST);
use LWP::UserAgent;
$ua = LWP::UserAgent->new();
my $req = POST 'http://www.perl.com/cgi-bin/cpan_mod',
[ module => 'DB_File', readme => 1 ];
$content = $ua->request($req)->as_string;
如何解碼或建立 web 中的 %-encoding?
If you are writing a CGI script, you should be using the CGI.pm module that comes with
perl, or some other equivalent module. The CGI module automatically decodes queries for
you, and provides an escape() function to handle encoding.
The best source of detailed information on URI encoding is RFC 2396. Basically, the
following substitutions do it:
s/([^\w()'*~!.-])/sprintf '%%%02x', ord $1/eg; # encode
s/%([A-Fa-f\d]{2})/chr hex $1/eg; # decode
However, you should only apply them to individual URI components, not the entire URI,
otherwise you'll lose information and generally mess things up. If that didn't explain
it, don't worry. Just go read section 2 of the RFC, it's probably the best explanation
there is.
RFC 2396 also contains a lot of other useful information, including a regexp for breaking
any arbitrary URI into components (Appendix B).
如何重定向到其他頁面？
Specify the complete URL of the destination (even if it is on the same server). This is
one of the two different kinds of CGI "Location:" responses which are defined in the CGI
specification for a Parsed Headers script. The other kind (an absolute URLpath) is
resolved internally to the server without any HTTP redirection. The CGI specifications do
not allow relative URLs in either case.
Use of CGI.pm is strongly recommended. This example shows redirection with a complete
URL. This redirection is handled by the web browser.
use CGI qw/:standard/;
my $url = 'http://www.cpan.org/';
print redirect($url);
This example shows a redirection with an absolute URLpath. This redirection is handled by
the local web server.
my $url = '/CPAN/index.html';
print redirect($url);
But if coded directly, it could be as follows (the final "\n" is shown separately, for
clarity), using either a complete URL or an absolute URLpath.
print "Location: $url\n"; # CGI response header
print "\n"; # end of headers
如何為我的網頁加上密碼？
要啟用 web 伺服器的驗證，你需要配置你的 web 伺服器，不同的伺服器有不同的方法---apache 與
iPlanet 不同，後者又與 IIS 不同。從你的 web 伺服器的文件中查詢特定伺服器的配置細節。
如何用 Perl 修改我的 .htpasswd 和 .htgroup 檔案?
HTTPD::UserAdmin 和 HTTPD::GroupAdmin 等模組為這些檔案提供了統一的物件導向介面，儘管這些檔
案可能以各種不同的格式儲存。這些資料庫可能是純文字格式、 dbm、Berkeley DB或任何 DBI相容的
資料庫驅動程式 (drivers)。 HTTPD::UserAdmin支援`Basic' 和 `Digest'這兩個認證模式所用的檔
案。以下是 一例：
use HTTPD::UserAdmin ();
HTTPD::UserAdmin
->new(DB => "/foo/.htpasswd")
->add($username => $password);
如何確保使用者不會在表單中輸入使我的 CGI 指令碼作壞事的值？
閱讀 CGI Meta FAQ 列出的安全索引
http://www.perl.org/CGI_MetaFAQ.html
如何解釋一個郵件頭？
要使用一個快速的方法，可以這樣使用 perlfunc 中的 "split" 函式：
$/ = '';
$header = <MSG>;
$header =~ s/\n\s+/ /g; # 將延續行合併成單行
%head = ( UNIX_FROM_LINE, split /^([-\w]+):\s*/m, $header );
但是，如果您若想保留所有 Received欄位資料的話【因 Received 欄位通常不止一個】，這個解法便
不太行了。一個完整的解法是使用收錄在 CPAN的 Mail::Header 模組（ MailTools 套件的一部分）。
如何解碼一個 CGI 表單？
使用標準模組，應該是 CGI.pm。沒有理由去嘗試手動去做！
你大概都看過一大堆從 STDIN 讀取與 $ENV{CONTENT_LENGTH} 長度相同的位元組，或者獲取
$ENV{QUERY_STRING} 來解碼 GET。這些程式都非常糟糕。他們僅在某些時候工作。他們通常不檢查
read() 的返回值，這是主要的錯誤。他們不處理 HEAD 請求。他們不處理檔案上載時的多成分表
單。They don't deal with GET/POST combinations where query fields are in more than one
place. They don't deal with keywords in the query string.
In short, they're bad hacks. Resist them at all costs. Please do not be tempted to
reinvent the wheel. Instead, use the CGI.pm or CGI_Lite.pm (available from CPAN), or if
you're trapped in the module-free land of perl1 .. perl4, you might look into cgi-lib.pl
(available from http://cgi-lib.stanford.edu/cgi-lib/ ).
Make sure you know whether to use a GET or a POST in your form. GETs should only be used
for something that doesn't update the server. Otherwise you can get mangled databases and
repeated feedback mail messages. The fancy word for this is ``idempotency''. This simply
means that there should be no difference between making a GET request for a particular URL
once or multiple times. This is because the HTTP protocol definition says that a GET
request may be cached by the browser, or server, or an intervening proxy. POST requests
cannot be cached, because each request is independent and matters. Typically, POST
requests change or depend on state on the server (query or update a database, send mail,
or purchase a computer).
如何檢測一個有效的郵件地址？
沒有辦法。至少，沒有可行的辦法。
如果沒有寄封信到一個位址去試試看它會不會彈回來（即使是這麼做您還得面對停頓的問題），您是無
法確定一個位址是否真的存在的。即使您套用 email 標頭的標準規格來做檢查的依據，您還是有可能
會遇到問題，因為有些送得到的位址並不 符合 RFC-822（電子郵件標頭的標準）的規定，但有些符合
標準的位址卻無法投 遞。
You can use the Email::Valid or RFC::RFC822::Address which check the format of the
address, although they cannot actually tell you if it is a deliverable address (i.e. that
mail to the address will not bounce). Modules like Mail::CheckUser and Mail::EXPN try to
interact with the domain name system or particular mail servers to learn even more, but
their methods do not work everywhere---especially for security conscious administrators.
許多人試圖用一個簡單的正規表示式，例如 "/^[\w.-]+\@(?:[\w-]+\.)+\w+$/" 來消除一些通常是無
效的 email 位址。不過，這樣做也把很多合格的位址給一起濾掉了，而且對測試一個位址有沒有希望
投遞成功完全沒有幫助，所以在此建議大家不要這麼做；不過您可以看看：
http://www.cpan.org/authors/Tom_Christiansen/scripts/ckaddr.gz , 這個 script真的徹底地依據
所有的 RFC規定來做檢驗（除了內嵌式 comments外）,同時會排除一些您可能不會想送信去的位址（如
Bill Clinton【美國總統】或您的 postmaster），然後它會確定位址中的主機名稱可在 DNS中找得
到。這個 script 跑起來不是很快，但至少有效。
Our best advice for verifying a person's mail address is to have them enter their address
twice, just as you normally do to change a password. This usually weeds out typos. If
both versions match, send mail to that address with a personal message that looks somewhat
like:
Dear someuser@host.com,
Please confirm the mail address you gave us Wed May 6 09:38:41
MDT 1998 by replying to this message. Include the string
"Rumpelstiltskin" in that reply, but spelled in reverse; that is,
start with "Nik...". Once this is done, your confirmed address will
be entered into our records.
If you get the message back and they've followed your directions, you can be reasonably
assured that it's real.
A related strategy that's less open to forgery is to give them a PIN (personal ID number).
Record the address and PIN (best that it be a random one) for later processing. In the
mail you send, ask them to include the PIN in their reply. But if it bounces, or the
message is included via a ``vacation'' script, it'll be there anyway. So it's best to ask
them to mail back a slight alteration of the PIN, such as with the characters reversed,
one added or subtracted to each digit, etc.
如何解碼一個 MIME/BASE64 字串?
MIME-tools套件（可自 CPAN取得）不但可處理這個問題而且有許多其他的功能。有了這個套件，解
BASE64碼就變得像這麼容易：
use MIME::Base64;
$decoded = decode_base64($encoded);
The MIME-Tools package (available from CPAN) supports extraction with decoding of BASE64
encoded attachments and content directly from email messages.
一個比較直接的解法是先做一點簡單的轉譯，然後使用 unpack()這個函式的 ``u'' 格式：
tr#A-Za-z0-9+/##cd; # remove non-base64 chars
tr#A-Za-z0-9+/# -_#; # convert to uuencoded format
$len = pack("c", 32 + 0.75*length); # compute length byte
print unpack("u", $len . $_); # uudecode and print
如何返回使用者的郵件地址？
On systems that support getpwuid, the $< variable, and the Sys::Hostname module (which is
part of the standard perl distribution), you can probably try using something like this:
use Sys::Hostname;
$address = sprintf('%s@%s', scalar getpwuid($<), hostname);
Company policies on mail address can mean that this generates addresses that the company's
mail system will not accept, so you should ask for users' mail addresses when this
matters. Furthermore, not all systems on which Perl runs are so forthcoming with this
information as is Unix.
The Mail::Util module from CPAN (part of the MailTools package) provides a mailaddress()
function that tries to guess the mail address of the user. It makes a more intelligent
guess than the code above, using information given when the module was installed, but it
could still be incorrect. Again, the best way is often just to ask the user.
如何發郵件？
Use the "sendmail" program directly:
open(SENDMAIL, "⎪/usr/lib/sendmail -oi -t -odq")
or die "Can't fork for sendmail: $!\n";
print SENDMAIL <<"EOF";
From: User Originating Mail <me\@host>
To: Final Destination <you\@otherhost>
Subject: A relevant subject line
Body of the message goes here after the blank line
in as many lines as you like.
EOF
close(SENDMAIL) or warn "sendmail didn't close nicely";
The -oi option prevents sendmail from interpreting a line consisting of a single dot as
"end of message". The -t option says to use the headers to decide who to send the message
to, and -odq says to put the message into the queue. This last option means your message
won't be immediately delivered, so leave it out if you want immediate delivery.
Alternate, less convenient approaches include calling mail (sometimes called mailx)
directly or simply opening up port 25 have having an intimate conversation between just
you and the remote SMTP daemon, probably sendmail.
Or you might be able use the CPAN module Mail::Mailer:
use Mail::Mailer;
$mailer = Mail::Mailer->new();
$mailer->open({ From => $from_address,
To => $to_address,
Subject => $subject,
})
or die "Can't open: $!\n";
print $mailer $body;
$mailer->close();
The Mail::Internet module uses Net::SMTP which is less Unix-centric than Mail::Mailer, but
less reliable. Avoid raw SMTP commands. There are many reasons to use a mail transport
agent like sendmail. These include queuing, MX records, and security.
如何使用 MIME 來為郵件訊息增加附件？
This answer is extracted directly from the MIME::Lite documentation. Create a multipart
message (i.e., one with attachments).
use MIME::Lite;
### Create a new multipart message:
$msg = MIME::Lite->new(
From =>'me@myhost.com',
To =>'you@yourhost.com',
Cc =>'some@other.com, some@more.com',
Subject =>'A message with 2 parts...',
Type =>'multipart/mixed'
);
### Add parts (each "attach" has same arguments as "new"):
$msg->attach(Type =>'TEXT',
Data =>"Here's the GIF file you wanted"
);
$msg->attach(Type =>'image/gif',
Path =>'aaa000123.gif',
Filename =>'logo.gif'
);
$text = $msg->as_string;
MIME::Lite also includes a method for sending these things.
$msg->send;
This defaults to using sendmail but can be customized to use SMTP via Net::SMTP.
如何讀郵件？
While you could use the Mail::Folder module from CPAN (part of the MailFolder package) or
the Mail::Internet module from CPAN (part of the MailTools package), often a module is
overkill. Here's a mail sorter.
#!/usr/bin/perl
my(@msgs, @sub);
my $msgno = -1;
$/ = ''; # paragraph reads
while (<>) {
if (/^From /m) {
/^Subject:\s*(?:Re:\s*)*(.*)/mi;
$sub[++$msgno] = lc($1) ⎪⎪ '';
}
$msgs[$msgno] .= $_;
}
for my $i (sort { $sub[$a] cmp $sub[$b] ⎪⎪ $a <=> $b } (0 .. $#msgs)) {
print $msgs[$i];
}
Or more succinctly,
#!/usr/bin/perl -n00
# bysub2 - awkish sort-by-subject
BEGIN { $msgno = -1 }
$sub[++$msgno] = (/^Subject:\s*(?:Re:\s*)*(.*)/mi)[0] if /^From/m;
$msg[$msgno] .= $_;
END { print @msg[ sort { $sub[$a] cmp $sub[$b] ⎪⎪ $a <=> $b } (0 .. $#msg) ] }
如何找到我的主機名/域名/IP 地址？
長久以來許多 code都很草率地直接呼叫 `hostname` 這個程式來取得主機名。雖然這麼做很方便，但
也同時增加了移植到其他平臺上的困難。這是一個很典型的例子，在方便和可移植性之間作抉擇，不論
選哪一邊，必須付出一些犧牲和代價。
Sys::Hostname這個模組（標準 perl發行的一部分）可用來取得機器的名字，然後您便可利用
gethostbyname()這個系統呼叫來找出該機的 IP位址了（假定您的 DNS 運作正常）。
use Socket;
use Sys::Hostname;
my $host = hostname();
my $addr = inet_ntoa(scalar gethostbyname($host ⎪⎪ 'localhost'));
至少在 Unix 底下，取得 DNS網域名最簡單的方法大概要算是直接從 /etc/resolv.conf 這個檔案裡面
找。當然，這麼做的前提是 resolv.conf 這個檔案的設定必須照慣例的格式，還有就是這個檔案必先
存在才行。
(Perl在非 Unix系統下尚需要一有效的方法來測出機器和網域名)
如何獲取一篇新聞文章或活動的新聞組？
使用 Net::NNTP或 News::NNTPClient模組，兩者皆可自 CPAN下載。這些模組讓抓群組名錄這類的差事
變得這麼容易：
perl -MNews::NNTPClient
-e 'print News::NNTPClient->new->list("newsgroups")'
如何獲取/上傳一個 FTP 檔案?
LWP::Simple模組（可自 CPAN下載）可以抓，但不能上傳檔案。 Net::FTP模組（也可自 CPAN下載）雖
比較複雜，但可用來上傳、也能抓檔案。
如何進行遠端過程呼叫 RPC ?
模組 DCE::RPC 正在開發中 (但是還不可用)，將成為 DCE-Perl 包 (可以從 CPAN 下載) 的一部
分。rpcgen 套件，可以從 CPAN/authors/id/JAKE/ 找到，是一個 RPC 存根生成器，包含一個
RPC::ONC 模組。
AUTHOR AND COPYRIGHT
Copyright (c) 1997-2002 Tom Christiansen and Nathan Torkington. All rights reserved.
This documentation is free; you can redistribute it and/or modify it under the same terms
as Perl itself.
Irrespective of its distribution, all code examples in this file are hereby placed into
the public domain. You are permitted and encouraged to use this code in your own programs
for fun or for profit as you see fit. A simple comment in the code giving credit would be
courteous but is not required.
譯者
蕭百齡，兩隻老虎工作室
跋
本頁面中文版由中文 man 手冊頁計劃提供。
中文 man 手冊頁計劃：https://github.com/man-pages-zh/manpages-zh