NAME

       DBIx::Class::FilterColumn - Automatically convert column data

SYNOPSIS

       In your Schema or DB class add "FilterColumn" to the top of the component list.

         __PACKAGE__->load_components(qw( FilterColumn ... ));

       Set up filters for the columns you want to convert.

        __PACKAGE__->filter_column( money => {
            filter_to_storage => 'to_pennies',
            filter_from_storage => 'from_pennies',
        });

        sub to_pennies   { $_[1] * 100 }

        sub from_pennies { $_[1] / 100 }

        1;

DESCRIPTION

       This component is meant to be a more powerful, but less DWIM-y,
       DBIx::Class::InflateColumn.  One of the major issues with said component is that it only
       works with references.  Generally speaking anything that can be done with
       DBIx::Class::InflateColumn can be done with this component.

METHODS

   filter_column
        __PACKAGE__->filter_column( colname => {
            filter_from_storage => 'method'|\&coderef,
            filter_to_storage   => 'method'|\&coderef,
        })

       This is the method that you need to call to set up a filtered column. It takes exactly two
       arguments; the first being the column name the second being a hash reference with
       "filter_from_storage" and "filter_to_storage" set to either a method name or a code
       reference. In either case the filter is invoked as:

         $row_obj->$filter_specification ($value_to_filter)

       with $filter_specification being chosen depending on whether the $value_to_filter is being
       retrieved from or written to permanent storage.

       If a specific directional filter is not specified, the original value will be passed
       to/from storage unfiltered.

   get_filtered_column
        $obj->get_filtered_column('colname')

       Returns the filtered value of the column

   set_filtered_column
        $obj->set_filtered_column(colname => 'new_value')

       Sets the filtered value of the column

EXAMPLE OF USE

       Some databases have restrictions on values that can be passed to boolean columns, and
       problems can be caused by passing value that perl considers to be false (such as "undef").

       One solution to this is to ensure that the boolean values are set to something that the
       database can handle - such as numeric zero and one, using code like this:-

           __PACKAGE__->filter_column(
               my_boolean_column => {
                   filter_to_storage   => sub { $_[1] ? 1 : 0 },
               }
           );

       In this case the "filter_from_storage" is not required, as just passing the database value
       through to perl does the right thing.

INHERITED METHODS

       DBIx::Class::Row
           copy, delete, discard_changes, get_dirty_columns, get_from_storage,
           get_inflated_columns, has_column_loaded, in_storage, inflate_result, insert,
           insert_or_update, is_changed, is_column_changed, make_column_dirty, register_column,
           result_source, set_column, set_columns, set_inflated_columns, throw_exception,
           update_or_insert