NAME

       Mojo::URL - Uniform Resource Locator

SYNOPSIS

         use Mojo::URL;

         # Parse
         my $url
           = Mojo::URL->new('http://sri:foobar@example.com:3000/foo/bar?foo=bar#23');
         say $url->scheme;
         say $url->userinfo;
         say $url->host;
         say $url->port;
         say $url->path;
         say $url->query;
         say $url->fragment;

         # Build
         my $url = Mojo::URL->new;
         $url->scheme('http');
         $url->userinfo('sri:foobar');
         $url->host('example.com');
         $url->port(3000);
         $url->path('/foo/bar');
         $url->query->param(foo => 'bar');
         $url->fragment(23);
         say "$url";

DESCRIPTION

       Mojo::URL implements a subset of RFC 3986 and RFC 3987 for Uniform Resource Locators with
       support for IDNA and IRIs.

ATTRIBUTES

       Mojo::URL implements the following attributes.

   base
         my $base = $url->base;
         $url     = $url->base(Mojo::URL->new);

       Base of this URL, defaults to a Mojo::URL object.

   fragment
         my $fragment = $url->fragment;
         $url         = $url->fragment('foo');

       Fragment part of this URL.

   host
         my $host = $url->host;
         $url     = $url->host('127.0.0.1');

       Host part of this URL.

   port
         my $port = $url->port;
         $url     = $url->port(8080);

       Port part of this URL.

   scheme
         my $scheme = $url->scheme;
         $url       = $url->scheme('http');

       Scheme part of this URL.

   userinfo
         my $userinfo = $url->userinfo;
         $url         = $url->userinfo('root:pass%3Bw0rd');

       Userinfo part of this URL.

METHODS

       Mojo::URL inherits all methods from Mojo::Base and implements the following new ones.

   new
         my $url = Mojo::URL->new;
         my $url = Mojo::URL->new('http://127.0.0.1:3000/foo?f=b&baz=2#foo');

       Construct a new Mojo::URL object and "parse" URL if necessary.

   authority
         my $authority = $url->authority;
         $url          = $url->authority('root:pass%3Bw0rd@localhost:8080');

       Authority part of this URL.

   clone
         my $url2 = $url->clone;

       Clone this URL.

   ihost
         my $ihost = $url->ihost;
         $url      = $url->ihost('xn--bcher-kva.ch');

       Host part of this URL in punycode format.

         # "xn--da5b0n.net"
         Mojo::URL->new('http://X.net')->ihost;

   is_abs
         my $bool = $url->is_abs;

       Check if URL is absolute.

   parse
         $url = $url->parse('http://127.0.0.1:3000/foo/bar?fo=o&baz=23#foo');

       Parse relative or absolute URL.

         # "/test/123"
         $url->parse('/test/123?foo=bar')->path;

         # "example.com"
         $url->parse('http://example.com/test/123?foo=bar')->host;

         # "sri@example.com"
         $url->parse('mailto:sri@example.com')->path;

   path
         my $path = $url->path;
         $url     = $url->path('/foo/bar');
         $url     = $url->path('foo/bar');
         $url     = $url->path(Mojo::Path->new);

       Path part of this URL, relative paths will be merged with the existing path, defaults to a
       Mojo::Path object.

         # "http://example.com/DOM/HTML"
         Mojo::URL->new('http://example.com/perldoc/Mojo')->path('/DOM/HTML');

         # "http://example.com/perldoc/DOM/HTML"
         Mojo::URL->new('http://example.com/perldoc/Mojo')->path('DOM/HTML');

         # "http://example.com/perldoc/Mojo/DOM/HTML"
         Mojo::URL->new('http://example.com/perldoc/Mojo/')->path('DOM/HTML');

   protocol
         my $proto = $url->protocol;

       Normalized version of "scheme".

         # "http"
         Mojo::URL->new('HtTp://example.com')->protocol;

   query
         my $query = $url->query;
         $url      = $url->query(replace => 'with');
         $url      = $url->query([merge => 'with']);
         $url      = $url->query({append => 'to'});
         $url      = $url->query(Mojo::Parameters->new);

       Query part of this URL, pairs in an array will be merged and pairs in a hash appended,
       defaults to a Mojo::Parameters object.

         # "2"
         Mojo::URL->new('http://example.com?a=1&b=2')->query->param('b');

         # "http://example.com?a=2&c=3"
         Mojo::URL->new('http://example.com?a=1&b=2')->query(a => 2, c => 3);

         # "http://example.com?a=2&a=3"
         Mojo::URL->new('http://example.com?a=1&b=2')->query(a => [2, 3]);

         # "http://example.com?a=2&b=2&c=3"
         Mojo::URL->new('http://example.com?a=1&b=2')->query([a => 2, c => 3]);

         # "http://example.com?b=2"
         Mojo::URL->new('http://example.com?a=1&b=2')->query([a => undef]);

         # "http://example.com?a=1&b=2&a=2&c=3"
         Mojo::URL->new('http://example.com?a=1&b=2')->query({a => 2, c => 3});

   to_abs
         my $abs = $url->to_abs;
         my $abs = $url->to_abs(Mojo::URL->new('http://example.com/foo'));

       Clone relative URL and turn it into an absolute one using "base" or provided base URL.

         # "http://example.com/foo/baz.xml?test=123"
         Mojo::URL->new('baz.xml?test=123')
           ->to_abs(Mojo::URL->new('http://example.com/foo/bar.html'));

         # "http://example.com/baz.xml?test=123"
         Mojo::URL->new('/baz.xml?test=123')
           ->to_abs(Mojo::URL->new('http://example.com/foo/bar.html'));

         # "http://example.com/foo/baz.xml?test=123"
         Mojo::URL->new('//example.com/foo/baz.xml?test=123')
           ->to_abs(Mojo::URL->new('http://example.com/foo/bar.html'));

   to_string
         my $str = $url->to_string;
         my $str = "$url";

       Turn URL into a string.

SEE ALSO

       Mojolicious, Mojolicious::Guides, <http://mojolicio.us>.