NAME

       Template::Stash - Magical storage for template variables

SYNOPSIS

           use Template::Stash;

           my $stash = Template::Stash->new(\%vars);

           # get variable values
           $value = $stash->get($variable);
           $value = $stash->get(\@compound);

           # set variable value
           $stash->set($variable, $value);
           $stash->set(\@compound, $value);

           # default variable value
           $stash->set($variable, $value, 1);
           $stash->set(\@compound, $value, 1);

           # set variable values en masse
           $stash->update(\%new_vars)

           # methods for (de-)localising variables
           $stash = $stash->clone(\%new_vars);
           $stash = $stash->declone();

DESCRIPTION

       The "Template::Stash" module defines an object class which is used to store variable
       values for the runtime use of the template processor.  Variable values are stored
       internally in a hash reference (which itself is blessed to create the object) and are
       accessible via the get() and set() methods.

       Variables may reference hash arrays, lists, subroutines and objects as well as simple
       values.  The stash automatically performs the right magic when dealing with variables,
       calling code or object methods, indexing into lists, hashes, etc.

       The stash has clone() and declone() methods which are used by the template processor to
       make temporary copies of the stash for localising changes made to variables.

PUBLIC METHODS

   new(\%params)
       The "new()" constructor method creates and returns a reference to a new "Template::Stash"
       object.

           my $stash = Template::Stash->new();

       A hash reference may be passed to provide variables and values which should be used to
       initialise the stash.

           my $stash = Template::Stash->new({ var1 => 'value1',
                                              var2 => 'value2' });

   get($variable)
       The "get()" method retrieves the variable named by the first parameter.

           $value = $stash->get('var1');

       Dotted compound variables can be retrieved by specifying the variable elements by
       reference to a list.  Each node in the variable occupies two entries in the list.  The
       first gives the name of the variable element, the second is a reference to a list of
       arguments for that element, or 0 if none.

           [% foo.bar(10).baz(20) %]

           $stash->get([ 'foo', 0, 'bar', [ 10 ], 'baz', [ 20 ] ]);

   set($variable, $value, $default)
       The "set()" method sets the variable name in the first parameter to the value specified in
       the second.

           $stash->set('var1', 'value1');

       If the third parameter evaluates to a true value, the variable is set only if it did not
       have a true value before.

           $stash->set('var2', 'default_value', 1);

       Dotted compound variables may be specified as per get() above.

           [% foo.bar = 30 %]

           $stash->set([ 'foo', 0, 'bar', 0 ], 30);

       The magical variable '"IMPORT"' can be specified whose corresponding value should be a
       hash reference.  The contents of the hash array are copied (i.e. imported) into the
       current namespace.

           # foo.bar = baz, foo.wiz = waz
           $stash->set('foo', { 'bar' => 'baz', 'wiz' => 'waz' });

           # import 'foo' into main namespace: bar = baz, wiz = waz
           $stash->set('IMPORT', $stash->get('foo'));

   update($variables)
       This method can be used to set or update several variables in one go.

           $stash->update({
               foo => 10,
               bar => 20,
           });

   getref($variable)
       This undocumented feature returns a closure which can be called to get the value of a
       variable.  It is used to implement variable references which are evlauted lazily.

           [% x = \foo.bar.baz %]          # x is a reference to foo.bar.baz
           [% x %]                         # evalautes foo.bar.baz

   clone(\%params)
       The "clone()" method creates and returns a new "Template::Stash" object which represents a
       localised copy of the parent stash. Variables can be freely updated in the cloned stash
       and when declone() is called, the original stash is returned with all its members intact
       and in the same state as they were before "clone()" was called.

       For convenience, a hash of parameters may be passed into "clone()" which is used to update
       any simple variable (i.e. those that don't contain any namespace elements like "foo" and
       "bar" but not "foo.bar") variables while cloning the stash.  For adding and updating
       complex variables, the set() method should be used after calling "clone()."  This will
       correctly resolve and/or create any necessary namespace hashes.

       A cloned stash maintains a reference to the stash that it was copied from in its "_PARENT"
       member.

   declone()
       The "declone()" method returns the "_PARENT" reference and can be used to restore the
       state of a stash as described above.

   define_vmethod($type, $name, $code)
       This method can be used to define new virtual methods.  The first argument should be
       either "scalar" or "item" to define scalar virtual method, "hash" to define hash virtual
       methods, or either "array" or "list" for list virtual methods.  The second argument should
       be the name of the new method.  The third argument should be a reference to a subroutine
       implementing the method.  The data item on which the virtual method is called is passed to
       the subroutine as the first argument.

           $stash->define_vmethod(
               item => ucfirst => sub {
                   my $text = shift;
                   return ucfirst $text
               }
           );

INTERNAL METHODS

   dotop($root, $item, \@args, $lvalue)
       This is the core "dot" operation method which evaluates elements of variables against
       their root.

   undefined($ident, $args)
       This method is called when get() encounters an undefined value.  If the
       "STRICT|Template::Manual::Config#STRICT" option is in effect then it will throw an
       exception indicating the use of an undefined value.  Otherwise it will silently return an
       empty string.

       The method can be redefined in a subclass to implement alternate handling of undefined
       values.

AUTHOR

       Andy Wardley <abw@wardley.org> <http://wardley.org/>

COPYRIGHT

       Copyright (C) 1996-2012 Andy Wardley.  All Rights Reserved.

       This module is free software; you can redistribute it and/or modify it under the same
       terms as Perl itself.

SEE ALSO

       Template, Template::Context