NAME

       Config::Model::Backend::Any - Virtual class for other backends

VERSION

       version 2.082

SYNOPSIS

        package Config::Model::Backend::Foo ;
        use Mouse ;

        extends 'Config::Model::Backend::Any';

        # optional
        sub suffix {
          return '.foo';
        }

        # mandatory
        sub read {
           my $self = shift ;
           my %args = @_ ;

           # args are:
           # root       => './my_test',  # fake root directory, userd for tests
           # config_dir => /etc/foo',    # absolute path
           # file       => 'foo.conf',   # file name
           # file_path  => './my_test/etc/foo/foo.conf'
           # io_handle  => $io           # IO::File object
           # check      => yes|no|skip

           return 0 unless defined $args{io_handle} ; # or die?

           foreach ($args{io_handle}->getlines) {
               chomp ;
               s/#.*// ;
               next unless /\S/; # skip blank line

               # $data is 'foo=bar' which is compatible with load
               $self->node->load(step => $_, check => $args{check} ) ;
           }
           return 1 ;
        }

        # mandatory
        sub write {
           my $self = shift ;
           my %args = @_ ;

           # args are:
           # root       => './my_test',  # fake root directory, userd for tests
           # config_dir => /etc/foo',    # absolute path
           # file       => 'foo.conf',   # file name
           # file_path  => './my_test/etc/foo/foo.conf'
           # io_handle  => $io           # IO::File object
           # check      => yes|no|skip

           my $ioh = $args{io_handle} ;

           foreach my $elt ($self->node->get_element_name) {
               my $obj =  $self->node->fetch_element($elt) ;
               my $v   = $self->node->grab_value($elt) ;

               # write value
               $ioh->print(qq!$elt="$v"\n!) if defined $v ;
               $ioh->print("\n")            if defined $v ;
           }

           return 1;
        }

        no Mouse ;
        __PACKAGE__->meta->make_immutable ;

DESCRIPTION

       This Mouse class is to be inherited by other backend plugin classes

       See "read callback" in Config::Model::BackendMgr and "write callback" in
       Config::Model::BackendMgr for more details on the method that must be provided by any
       backend classes.

CONSTRUCTOR

   new ( node => $node_obj, name => backend_name )
       The constructor should be used only by Config::Model::Node.

Methods to override

   annotation
       Whether the backend supports reading and writing annotation (a.k.a comments). Default is
       0. Override this method to return 1 if your backend supports annotations.

   suffix
       Suffix of the configuration file. This method returns "undef"

   read
       Read the configuration file. This method must be overridden.

   write
       Write the configuration file. This method must be overridden.

Methods

   node
       Return the node (a Config::Model::Node) holding this backend.

   instance
       Return the instance (a Config::Model::Instance) holding this configuration.

   show_message( string )
       Show a message to STDOUT (unless overridden). Delegated to "show_message( string )" in
       Config::Model::Instance.

   read_global_comments( lines , comment_char)
       Read the global comments (i.e. the first block of comments until the first blank or non
       comment line) and store them as root node annotation. The first parameter ("lines")
        is an array ref containing file lines.

   associates_comments_with_data ( lines , comment_char)
       This method will extract comments from the passed lines and associate them with actual
       data found in the file lines. Data is associated with comments preceding or on the same
       line as the data. Returns a list of [ data, comment ] .

       Example:

         # Foo comments
         foo= 1
         Baz = 0 # Baz comments

       will return

         ( [  'foo= 1', 'Foo comments'  ] , [ 'Baz = 0' , 'Baz comments' ] )

   write_global_comments( io_handle , comment_char)
       Write global comments from configuration root annotation into the io_handle (if defined).
       Returns the string written to the io_handle.

   write_data_and_comments( io_handle , comment_char , data1, comment1, data2, comment2 ...)
       Write data and comments in the "io_handle" (if defined). Comments are written before the
       data.  Returns the string written to the io_handle. If a data is undef, the comment will
       be written on its own line.

AUTHOR

       Dominique Dumont, (ddumont at cpan dot org)

SEE ALSO

       Config::Model, Config::Model::BackendMgr, Config::Model::Node,
       Config::Model::Backend::Yaml,

AUTHOR

       Dominique Dumont

COPYRIGHT AND LICENSE

       This software is Copyright (c) 2005-2016 by Dominique Dumont.

       This is free software, licensed under:

         The GNU Lesser General Public License, Version 2.1, February 1999