NAME

       Tk::callbacks - Specifying code for Tk to call.

SYNOPSIS

       One can specify a callback in one of the following ways:

       Without arguments:

           ... => \&subname, ...
           ... => sub { ... }, ...
           ... => 'methodname', ...

       or with arguments:

           ... => [ \&subname, args ... ], ...
           ... => [ sub { ... }, args... ], ...
           ... => [ 'methodname', args... ], ...

DESCRIPTION

       Perl/Tk has a callback, where Tcl/Tk has a command string (i.e. a fragment of Tcl to be
       executed).  A perl/Tk callback can take one of the following basic forms:

       •   Reference to a subroutine "\&subname"

       •   Anonymous subroutine (closure) "sub { ... }"

       •   A method name 'methodname'

       Any of these can be provided with arguments by enclosing them and the arguments in [].
       Here are some examples:

       $mw->bind($class, "<Delete>" => 'Delete');

       This will call $widget->Delete, the $widget being provided (by bind) as the one where the
       Delete key was pressed.

       While having bind provide a widget object for you is ideal in many cases it can be
       irritating in others. Using the list form this behaviour can be modified:

       $a->bind("<Delete>",[$b => 'Delete']);

       because the first element $b is an object bind will call $b->Delete.

       Note that method/object ordering only matters for "bind" callbacks, the auto-quoting in
       perl5.001 makes the first of these a little more readable:

           $w->configure(-yscrollcommand => [ set => $ysb]);
           $w->configure(-yscrollcommand => [ $ysb => 'set' ]);

       but both will call $ysb->set(args provided by Tk)

       Another use of arguments allows you to write generalized methods which are easier to re-
       use:

           $a->bind("<Next>",['Next','Page']);
           $a->bind("<Down>",['Next','Line']);

       This will call $a->Next('Page') or $a->Next('Line') respectively.

       Note that the contents of the "[]" are evaluated by perl when the callback is created. It
       is often desirable for the arguments provided to the callback to depend on the details of
       the event which caused it to be executed. To allow for this callbacks can be nested using
       the Ev(...) "constructor".  Ev(...) inserts callback objects into the argument list. When
       perl/Tk glue code is preparing the argument list for the callback it is about to call it
       spots these special objects and recursively applies the callback process to them.

EXAMPLES

           $entry->bind('<Return>' => [$w , 'validate', Ev(['get'])]);

           $toplevel->bind('all', '<Visibility>', [\&unobscure, Ev('s')]);

           $mw->bind($class, '<Down>', ['SetCursor', Ev('UpDownLine',1)]);

SEE ALSO

       Tk::bind Tk::after Tk::options Tk::fileevent

KEYWORDS

       callback, closure, anonymous subroutine, bind